Suma de las últimas N columnas

Si tiene una tabla de datos que se actualiza con frecuencia, por ejemplo, se agrega una nueva columna cada mes, es posible que desee encontrar la suma de las últimas tres columnas. Pero no querrás reescribir tu fórmula cada vez que agregues una nueva columna. Afortunadamente, puedes realizar esta tarea con dos funciones de búsqueda, ÍNDICE y COLUMNAS.

Objetivo

Seamos claros sobre nuestros objetivos. Queremos escribir una fórmula que opere en las últimas tres columnas. No queremos modificar la fórmula cada vez que se agrega una nueva columna. Por ejemplo, la siguiente fórmula calcula la suma de las últimas tres columnas de la tabla, abril, mayo y junio.

El próximo mes, agregaremos una nueva columna de julio y queremos que nuestra fórmula sume automáticamente las últimas tres columnas de la tabla, mayo, junio y julio, como se muestra a continuación.

Las funciones COLUMNAS e ÍNDICE de Excel se pueden usar como argumentos en la función SUMA para que la fórmula sume automáticamente las últimas tres columnas de la tabla, incluso cuando se agregan nuevas columnas cada mes. Repasemos ahora los detalles de la fórmula.

Detalles

La fórmula básica comienza con una función SUMA estándar. Suponiendo que nuestra tabla se llama Tabla1, podríamos sumar todas las celdas de la tabla con la siguiente fórmula.

=SUMA(Tabla1)

Pero… no queremos sumar todas las celdas de la tabla, solo queremos sumar las celdas de las últimas tres columnas. Entonces, exploremos la función ÍNDICE para limitar la referencia de la tabla.

Si quisiéramos sumar las celdas en la segunda columna de la tabla, podríamos usar ÍNDICE para limitar la referencia de la siguiente manera.

=SUMA(ÍNDICE(Tabla1,0,2))

Dónde:

• Tabla1 es el rango completo de la tabla
• 0 significa que queremos incluir todas las filas dentro del rango
• 2 significa que queremos incluir la segunda columna dentro del rango

Digamos que en lugar de sumar la segunda columna, queremos sumar la última columna. En lugar de expresar el argumento con un valor entero como 2, queremos que Excel determine dinámicamente el número de la última columna. Esto nos lleva a la función COLUMNAS que devuelve el número de columnas dentro de un rango. Por ejemplo, la siguiente fórmula devolverá el número de columnas de nuestra tabla, que en este momento es 8.

=COLUMNAS(Tabla1)

A medida que cambia el número de columnas de la tabla, la función COLUMNAS también actualiza el resultado, de 8 a 9, a 10, etc.

Si quisiéramos sumar la última columna de la tabla, la columna 8, podríamos usar la siguiente fórmula.

=SUMA(ÍNDICE(Tabla1,0,COLUMNAS(Tabla1)))

Dónde:

• Tabla1 es la referencia de la tabla.
• 0 significa que queremos incluir todas las filas
• COLUMNAS(Tabla1) significa que queremos incluir la última columna

Pero… no queremos sumar la columna final, queremos sumar las tres columnas finales. No hay problema, podemos simplemente incluir otra función ÍNDICE. Básicamente, usaremos una función ÍNDICE para especificar la primera columna del rango deseado (columna 6) y otra función ÍNDICE para especificar la última columna del rango (columna 8).

Sabes que puedes usar el operador de rango (:) para especificar un rango usando referencias de celda, como A1:B10. También puede utilizar el operador de rango con dos funciones ÍNDICE, como ÍNDICE(…):ÍNDICE(…). En la siguiente fórmula, la primera función ÍNDICE hace referencia a la columna de mayo (8-2=6) y la segunda función ÍNDICE hace referencia a la columna de julio (columna 8).

=SUMA(ÍNDICE(Tabla1,0,COLUMNAS(Tabla1)-2):ÍNDICE(Tabla1,0,COLUMNAS(Tabla1)))

Dónde:

• INDEX(Table1,0,COLUMNS(Table1)-2 hace referencia a la columna de mayo
• INDEX(Table1,0,COLUMNS(Table1) hace referencia a la columna de julio

Dado que la función COLUMNAS se actualiza cada vez que se agrega una nueva columna, la fórmula devolverá la SUMA de las últimas tres columnas de la tabla. Si quisiera sumar las últimas 6 columnas, simplemente restaría 5 en lugar de 2 del argumento de columna de la primera función ÍNDICE. Si quisieras los últimos 12, restarías 11, y así sucesivamente.

Si tiene otros métodos para sumar las tres últimas columnas de la tabla, compártalos publicando un comentario a continuación… ¡gracias!

Nota

• Esta técnica también se puede utilizar para sumar las últimas n filas de datos… simplemente use la función FILAS como argumento de filas… como ÍNDICE (Tabla1, FILAS (Tabla1), 0)

Recursos adicionales

• Archivo de Excel de muestra
• Publicaciones de la función ÍNDICE