Función SECUENCIA en Excel (Cómo + 5 ejemplos)
La función SECUENCIA es una de las nuevas funciones de matriz dinámica que Microsoft lanzó como parte de la introducción de las matrices dinámicas. Esta función hace uso de cambios en el motor de cálculo de Excel , que permite que una sola fórmula muestre (o "derrame" si se usa la nueva terminología) los resultados en múltiples celdas. En el caso de SEQUENCE, generará una lista de números secuenciales en una matriz bidimensional en filas y columnas.
Al momento de escribir este artículo, la función SECUENCIA solo está disponible en Excel 2021, Excel 365 y Excel Online. No estará disponible en Excel 2019 o versiones anteriores.
Tabla de contenido
- Los argumentos de la función SECUENCIA.
- Ejemplos de uso de la función SECUENCIA
- Ejemplo 1: uso básico
- Ejemplo 2: uso de SECUENCIA dentro de otras funciones
- Ejemplo 3: orden de fila/columna de SECUENCIA
- Ejemplo 4 – Secuencia con ÍNDICE
- Ejemplo 5: SECUENCIA en orden aleatorio
- Otros ejemplos
Descargue el archivo de ejemplo: únase al programa Insiders gratuito y obtenga acceso al archivo de ejemplo utilizado para esta publicación.
Nombre del archivo: 0036 Función SECUENCIA en Excel.zip
Tener acceso
La función SECUENCIA tiene cuatro argumentos; Filas, Columnas, Inicio, Paso.
=SEQUENCE(Rows, [Columns], [Start], [Step])- Filas: el número de filas a devolver.
- [Columnas] (opcional): el número de columnas que se devolverán. Si se excluye, devolverá una sola columna.
- [Inicio] (opcional): El primer número de la secuencia. Si se excluye, comenzará en 1.
- [Paso] (opcional): La cantidad para incrementar cada valor posterior. Si se excluye, cada incremento será 1.
Tenga en cuenta que, mientras Excel crea secuencias en filas y columnas, se mueve entre las columnas antes de pasar a la siguiente fila. Mire el Ejemplo 3 para aprender cómo invertir esa funcionalidad.
Ejemplos de uso de la función SECUENCIA
Los siguientes ejemplos ilustran cómo utilizar la función SECUENCIA en Excel. Como función de matriz dinámica, el resultado se extenderá automáticamente a las filas y columnas vecinas.
Ejemplo 1: uso básico
Los dos ejemplos siguientes muestran el uso básico de la función SECUENCIA para proporcionar una secuencia de números.
Excluyendo argumentos opcionales
La fórmula en la celda B2 es:
=SEQUENCE(8)En esta fórmula, sólo se proporciona el argumento Filas; todos los demás argumentos ([Columnas] opcionales, [Inicio] opcional y [Paso] opcional) se han excluido. Por lo tanto, se aplican los valores predeterminados para cada uno de ellos. SEQUENCE ha creado una lista de números secuenciales; 8 filas, 1 columna, comenzando en 1 e incrementando en 1 para cada celda.
Incluyendo todos los argumentos.
La fórmula de la celda D2 utiliza todos los argumentos: Filas, Columnas, Inicio y Paso.
=SEQUENCE(8,3,5,10)Cuando se utilizan argumentos de filas y columnas, crea números secuenciales en una matriz bidimensional. La fórmula crea una matriz con:
- Argumento de filas = 8
- Argumento de columnas = 3
- Argumento inicial = 5
- Argumento del paso = 10
El orden de los números es importante aquí, la función aumenta a lo largo de las columnas antes de pasar a la siguiente fila.
Ejemplo 2: uso de SECUENCIA dentro de otras funciones
El siguiente ejemplo muestra cómo usar SECUENCIA dentro de la función FECHA.
Nota: Como resido en el Reino Unido, la siguiente captura de pantalla muestra el formato de fecha del Reino Unido (dd/mm/aaaa).
La fórmula en la celda B2 es:
=DATE(2020,SEQUENCE(13),1)Esta fórmula crea una secuencia de fechas mensuales a partir del 1 de enero de 2020. La función SECUENCIA se aplica al argumento del mes; por lo tanto, suma uno al mes por cada resultado posterior. Hemos solicitado 13 meses, pero Excel es lo suficientemente inteligente como para saber que el 13/01/2020 no existe como formato de fecha del Reino Unido. En cambio, la función FECHA hace que el resultado se transfiera al año siguiente y cree el 01/01/2021.
Ejemplo 3: orden de fila/columna de SECUENCIA
Como ya se mencionó, la fórmula SECUENCIA en Excel crea números secuenciales tanto en filas como en columnas. Sin embargo, de forma predeterminada, se incrementan en las columnas antes de pasar a la siguiente fila. Para cambiar esto, podemos usar la función TRANSPONER.
La fórmula en la celda B2 es:
=TRANSPOSE(SEQUENCE(8,3,5,10))Esta es la misma función SECUENCIA que usamos en el Ejemplo 1, pero ha sido envuelta en TRANSPOSE. Por lo tanto, ahora los números aumentan en cada fila antes de pasar a la siguiente columna.
Esto puede resultar un poco confuso ya que, aunque hemos utilizado los argumentos de filas y columnas, el argumento de filas muestra 8 columnas y el argumento de columna muestra 3 filas. Cuando utilizamos esta técnica, solo debemos recordar que TRANSPONER se aplica como última acción.
Ejemplo 4 – Secuencia con ÍNDICE
La fórmula SECUENCIA en Excel es útil por sí sola, pero cuando se combina con otras funciones su poder se puede ver claramente.
En la captura de pantalla a continuación, tenemos una lista de nombres y luego la identificación o departamento de la persona. Hay dos filas para cada individuo. ¿Cómo podemos obtener una lista solo de las identificaciones ordenadas por apellido? Vamos a averiguar:
La fórmula en la celda F2 es:
=SORT(INDEX(B3:D12,SEQUENCE(COUNTA(B3:B12)/2,1,1,2),SEQUENCE(1,3)),2)Analicemos esto:
- SECUENCIA(CONTARA(B3:B12)/2,1,1,2) : esta parte usa CONTARA para calcular el número de filas, luego lo divide por 2, ya que queremos devolver cada segunda fila. Luego se usa SECUENCIA para crear la lista, que es de 1 columna, comienza en la primera fila pero avanza en 2.
- SECUENCIA(1,3) : como tenemos 3 columnas en nuestra fuente, queremos devolver las mismas 3 columnas. Esto crea la lista de matrices para que la use INDEX.
- ÍNDICE (B3:D12,…..) – La primera función SECUENCIA anterior devuelve el valor {1, 3, 5, 7, 9, 11}, la segunda función SECUENCIA anterior devuelve los valores {1;2;3}. ÍNDICE devuelve solo los valores de B3-B12 que se encuentran en estas posiciones de fila y columna.
- SORT(….,2) – finalmente el resultado se ordena por la segunda columna, que es el apellido
Esto demuestra el poder de SEQUENCE como habilitador de funciones más complejas.
Ejemplo 5: SECUENCIA en orden aleatorio
¿Juegas al bingo? No yo tampoco. Pero crea un ejemplo interesante. Me hacen creer que hay 75 números y que esos números sólo pueden aparecer una vez. Combinando SORTBY , RANDARRAY y SEQUENCE podemos poner la secuencia de 75 números en un orden aleatorio (como en el bingo).
La fórmula en la celda B2 es:
=SORTBY(SEQUENCE(75),RANDARRAY(75))La función SECUENCIA devuelve una lista del 1 al 75. Esta lista está ordenada por otra lista de 75 números aleatorios creada por RANDARRAY.
Otros ejemplos
La publicación sobre la función ORDENAR también contiene un ejemplo del uso de la fórmula SECUENCIA en Excel para crear una lista de los 5 resultados principales.
¿Querer aprender más?
Hay mucho que aprender sobre las matrices dinámicas y las nuevas funciones. Consulte mis otras publicaciones aquí para obtener más información:
- Introducción a las matrices dinámicas : aprenda cómo ha cambiado el motor de cálculo de Excel.
- ÚNICO : para enumerar los valores únicos en un rango
- ORDENAR : para ordenar los valores en un rango
- SORTBY : para ordenar valores según el orden de otros valores
- FILTRO : para devolver solo los valores que cumplen criterios específicos
- SECUENCIA : para devolver una secuencia de números en filas y columnas
- RANDARRAY : para devolver una matriz de números aleatorios en un número específico de filas y columnas
- Uso de matrices dinámicas con otras funciones de Excel : aprenda a usar matrices dinámicas con gráficos, tablas dinámicas, imágenes, etc.
- Técnicas avanzadas de fórmulas de matrices dinámicas : aprenda las técnicas avanzadas para gestionar matrices dinámicas
Deja una respuesta